TusLibros-8.st

!classDefinition: #CartTest category: #TusLibros!
TestCase subclass: #CartTest
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!CartTest methodsFor: 'tests' stamp: 'HernanWilkinson 6/17/2013 17:08'!
test01NewCartsAreCreatedEmpty

	self assert: self createCart isEmpty! !

!CartTest methodsFor: 'tests' stamp: 'HernanWilkinson 6/17/2013 17:45'!
test02CanNotAddItemsThatDoNotBelongToStore

	| cart |
	
	cart := self createCart.
	
	self 
		should: [ cart add: self itemNotSellByTheStore ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: anError messageText = cart invalidItemErrorMessage.
			self assert: cart isEmpty ]! !

!CartTest methodsFor: 'tests' stamp: 'HernanWilkinson 6/17/2013 17:43'!
test03AfterAddingAnItemTheCartIsNotEmptyAnymore

	| cart |
	
	cart := self createCart.
	
	cart add: self itemSellByTheStore.
	self deny: cart isEmpty ! !

!CartTest methodsFor: 'tests' stamp: 'HernanWilkinson 6/17/2013 17:43'!
test04CanNotAddNonPositiveNumberOfItems

	| cart |
	
	cart := self createCart.
	
	self 
		should: [cart add: 0 of: self itemSellByTheStore ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: anError messageText = cart invalidQuantityErrorMessage.
			self assert: cart isEmpty ]! !

!CartTest methodsFor: 'tests' stamp: 'HernanWilkinson 6/17/2013 17:45'!
test05CanNotAddMoreThanOneItemNotSellByTheStore

	| cart |
	
	cart := self createCart.
	
	self 
		should: [cart add: 2 of: self itemNotSellByTheStore  ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: anError messageText = cart invalidItemErrorMessage.
			self assert: cart isEmpty ]! !

!CartTest methodsFor: 'tests' stamp: 'HernanWilkinson 6/17/2013 17:43'!
test06CartRemembersAddedItems

	| cart |
	
	cart := self createCart.
	
	cart add: self itemSellByTheStore.
	self assert: (cart includes: self itemSellByTheStore)! !

!CartTest methodsFor: 'tests' stamp: 'HernanWilkinson 6/17/2013 17:43'!
test07CartDoesNotHoldNotAddedItems

	| cart |
	
	cart := self createCart.
	
	self deny: (cart includes: self itemSellByTheStore)! !

!CartTest methodsFor: 'tests' stamp: 'HernanWilkinson 6/17/2013 17:45'!
test08CartRemembersTheNumberOfAddedItems

	| cart |
	
	cart := self createCart.
	
	cart add: 2 of: self itemSellByTheStore.
	self assert: (cart occurrencesOf: self itemSellByTheStore) = 2! !

!CartTest methodsFor: 'tests' stamp: 'MA 7/12/2020 21:17:54'!
test09EmptyCartShowsZeroCost

	| cart |
	
	cart := self createCart.
	
	self assert: 0 equals: cart totalValue.! !

!CartTest methodsFor: 'tests' stamp: 'MA 7/12/2020 21:16:37'!
test10CartKnowsTheTotalCostOfItsLoad

	| cart |
	
	cart := self createCart.
	cart add: 5 of: self itemSellByTheStore .
	
	self assert: 500 equals: cart totalValue.! !

!CartTest methodsFor: 'tests' stamp: 'MA 7/12/2020 23:33:34'!
test11CartBecomesEmptyAfterClearingItsContents

	| cart |
	
	cart := self createCart.
	cart add: 5 of: self itemSellByTheStore .
	cart clear.
	
	self assert: cart isEmpty.! !


!CartTest methodsFor: 'support' stamp: 'MA 7/12/2020 21:31:26'!
createCart
	
	^Cart acceptingItemsOf: self defaultCatalog .! !

!CartTest methodsFor: 'support' stamp: 'MA 7/12/2020 21:12:54'!
defaultCatalog
	
	| catalog |
	catalog _ Dictionary new.
	catalog at: (self itemSellByTheStore)  put: 100.
	^ catalog.! !

!CartTest methodsFor: 'support' stamp: 'HernanWilkinson 6/17/2013 17:44'!
itemNotSellByTheStore
	
	^'invalidBook'! !

!CartTest methodsFor: 'support' stamp: 'HernanWilkinson 6/17/2013 17:43'!
itemSellByTheStore
	
	^ 'validBook'! !


!classDefinition: #CashierPerSaleTest category: #TusLibros!
TestCase subclass: #CashierPerSaleTest
	instanceVariableNames: 'aValidCartValue aValidDate'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!CashierPerSaleTest methodsFor: 'tests' stamp: 'MA 7/14/2020 21:27:30'!
test01CannotCheckoutAnEmptyCart

	| cashier cart creditCard aSalesBook aMerchantProcessor |
	
	cart _ self createEmptyCart.
	creditCard _ self createValidCreditCard.	
	aSalesBook _ self createSalesBook.
	aMerchantProcessor _ self createMerchantProcessor.	
		
	cashier _ CashierPerSale usingSalesBook: aSalesBook usingMerchantProcessor: aMerchantProcessor.	
	
	self 
		should: [ cashier checkout: cart payingWith: creditCard onDate: aValidDate]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cashier emptyCartErrorMessage equals: anError messageText.
			self assert: aSalesBook receivedNoMessages.
			self assert: aMerchantProcessor receivedNoMessages ].! !

!CashierPerSaleTest methodsFor: 'tests' stamp: 'MA 7/14/2020 21:27:30'!
test02CannotCheckoutWithAnInvalidCreditCard

	| cashier cart creditCard aSalesBook aMerchantProcessor |
	
	cart _ self createCartWithItems.
	aSalesBook _ self createSalesBook.
	aMerchantProcessor _ self createMerchantProcessor.
	creditCard _ self createExpiredCreditCard.
	
	cashier _ CashierPerSale usingSalesBook: aSalesBook usingMerchantProcessor: aMerchantProcessor.
	
	self 
		should: [ cashier checkout: cart payingWith: creditCard onDate: aValidDate ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cashier invalidCreditCardErrorMessage equals: anError messageText.
			self assert: aSalesBook receivedNoMessages.
			self assert: aMerchantProcessor receivedNoMessages ].! !

!CashierPerSaleTest methodsFor: 'tests' stamp: 'MA 7/14/2020 21:27:30'!
test03AfterValidCheckoutSalesBookIsGivenANewSale

	| cashier cart creditCard aSalesBook aMerchantProcessor totalValue |
	
	cart _ self createCartWithItems.
	aSalesBook _ self createSalesBook.
	aMerchantProcessor _ self createMerchantProcessor.
	creditCard _ self createValidCreditCard.
	
	totalValue _ cart totalValue.

	cashier _ CashierPerSale usingSalesBook: aSalesBook usingMerchantProcessor: aMerchantProcessor.
	
	cashier checkout: cart payingWith: creditCard onDate: aValidDate.
	
	self assert: 1 equals: (aSalesBook timesReceivedSelector: #add: withArgs: { totalValue }).! !

!CashierPerSaleTest methodsFor: 'tests' stamp: 'MA 7/14/2020 21:27:30'!
test04AfterValidCheckoutCartGetsEmpty

	| cashier cart creditCard aSalesBook aMerchantProcessor |
	
	cart _ self createCartWithItems.
	aSalesBook _ self createSalesBook.
	aMerchantProcessor _ self createMerchantProcessor.
	creditCard _ self createValidCreditCard.
	
	cashier _ CashierPerSale usingSalesBook: aSalesBook usingMerchantProcessor: aMerchantProcessor.
	
	cashier checkout: cart payingWith: creditCard onDate: aValidDate.
	
	self assert: 1 equals: (cart timesReceivedSelector: #clear).! !

!CashierPerSaleTest methodsFor: 'tests' stamp: 'MA 7/14/2020 21:27:30'!
test05DuringAValidCheckoutCashierForwardsDebitToMerchantProcessor

	| cashier cart creditCard aSalesBook aMerchantProcessor cartTotalValue |
		
	cart _ self createCartWithItems.
	aSalesBook _ self createSalesBook.
	aMerchantProcessor _ self createMerchantProcessor.
	creditCard _ self createValidCreditCard.
	
	cartTotalValue _ cart totalValue.
	
	cashier _ CashierPerSale usingSalesBook: aSalesBook usingMerchantProcessor: aMerchantProcessor.
	
	cashier checkout: cart payingWith: creditCard onDate: aValidDate.
	
	self assert: 1 equals: (aMerchantProcessor timesReceivedSelector: #debit:from: withArgs: { cartTotalValue. creditCard. }).! !

!CashierPerSaleTest methodsFor: 'tests' stamp: 'MA 7/14/2020 21:30:13'!
test06IfMerchantProcessorDetectsInvalidCardCheckoutIsNotFullfilled

	| cashier cart creditCard aSalesBook aMerchantProcessor merchantProcessorErrorMessage |
	
	merchantProcessorErrorMessage _ 'card is stolen or has no funds'.
		
	cart _ self createCartWithItems.
	aSalesBook _ self createSalesBook.
	aMerchantProcessor _ self createMerchantProcessorThatRejectsCardWithErrorMessage: merchantProcessorErrorMessage .
	creditCard _ self createValidCreditCard.
	
	cashier _ CashierPerSale usingSalesBook: aSalesBook usingMerchantProcessor: aMerchantProcessor.
	
	self 
		should: [ cashier checkout: cart payingWith: creditCard onDate: aValidDate. ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: merchantProcessorErrorMessage equals: anError messageText.
			self assert: aSalesBook receivedNoMessages.
			self assert: 0 equals: (cart timesReceivedSelector: #clear) ].
! !


!CashierPerSaleTest methodsFor: 'support' stamp: 'MA 7/16/2020 17:07:12'!
createCartWithItems
	| cart |
	cart _ TestDouble new.
	cart when: #isEmpty do: [ false ].
	cart when: #totalValue do: [ aValidCartValue ].
	cart when: #clear do: [ ].	
	^ Spy on: cart! !

!CashierPerSaleTest methodsFor: 'support' stamp: 'MA 7/16/2020 17:07:25'!
createEmptyCart
	| cart |
	cart _ TestDouble new.
	cart when: #isEmpty do: [ true ].
	^ Spy on: cart! !

!CashierPerSaleTest methodsFor: 'support' stamp: 'MA 7/14/2020 21:13:36'!
createExpiredCreditCard
	| cc |
	cc := TestDouble new.
	cc when: #isValidOn: do: [ :aDate | false ].
	^ cc
! !

!CashierPerSaleTest methodsFor: 'support' stamp: 'MA 7/16/2020 17:07:37'!
createMerchantProcessor
	| mp |
	mp _ TestDouble new.
	mp when: #debit:from: do: [ :amount :card | ].
	^ Spy on: mp! !

!CashierPerSaleTest methodsFor: 'support' stamp: 'MA 7/16/2020 17:07:42'!
createMerchantProcessorThatRejectsCardWithErrorMessage: anErrorMessage
	| mp |
	mp _ TestDouble new.
	mp when: #debit:from: do: [ :amount :card | Error signal: anErrorMessage ].
	^ Spy on: mp! !

!CashierPerSaleTest methodsFor: 'support' stamp: 'MA 7/16/2020 17:07:48'!
createSalesBook
	| sb |
	sb _ TestDouble new.
	sb when: #add: do: [:amount | ].
	^ Spy on: sb.! !

!CashierPerSaleTest methodsFor: 'support' stamp: 'MA 7/14/2020 21:11:52'!
createValidCreditCard
	| cc |
	cc := TestDouble new.
	cc when: #isValidOn: do: [ :aDate | true ].
	^ cc
! !


!CashierPerSaleTest methodsFor: 'setUp/tearDown' stamp: 'MA 7/14/2020 21:20:05'!
setUp
	aValidCartValue _ 100.
	aValidDate _ '07/01/20'! !


!classDefinition: #CreditCardBuilderTest category: #TusLibros!
TestCase subclass: #CreditCardBuilderTest
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!CreditCardBuilderTest methodsFor: 'tests' stamp: 'MA 7/13/2020 15:02:04'!
test01CardCannotHaveAnEmptyOwnerName

	| cardBuilder |
	cardBuilder _ CreditCard builder.
	
	self
		should: [ cardBuilder setOwner: '' ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cardBuilder invalidOwnerErrorMessage equals: anError messageText ]! !

!CreditCardBuilderTest methodsFor: 'tests' stamp: 'MA 7/13/2020 15:36:01'!
test01CardCannotHaveAnOwnerNameLongerThan30Characters

	| cardBuilder |
	cardBuilder _ CreditCard builder.
	
	self
		should: [ cardBuilder setOwner: 'un nombre de mas de 30 caracteres' ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cardBuilder invalidOwnerErrorMessage equals: anError messageText ]! !

!CreditCardBuilderTest methodsFor: 'tests' stamp: 'MA 7/13/2020 15:02:24'!
test02ValidFromMustBeAValidDate

	| cardBuilder |
	cardBuilder _ CreditCard builder.
	
	self
		should: [ cardBuilder setValidFrom: 'abcd' ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cardBuilder invalidDateFormatErrorMessage equals: anError messageText ]! !

!CreditCardBuilderTest methodsFor: 'tests' stamp: 'MA 7/13/2020 15:02:41'!
test03ValidUntilMustBeAValidDate

	| cardBuilder |
	cardBuilder _ CreditCard builder.
	
	self
		should: [ cardBuilder setValidUntil: 'abcd' ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cardBuilder invalidDateFormatErrorMessage equals: anError messageText ]! !

!CreditCardBuilderTest methodsFor: 'tests' stamp: 'MA 7/13/2020 15:02:55'!
test04CardNumberMustBeANumber

	| cardBuilder |
	cardBuilder _ CreditCard builder.
	
	self
		should: [ cardBuilder setNumber: 'abcdefghijklmnop' ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cardBuilder invalidCardNumberFormatErrorMessage equals: anError messageText ]! !

!CreditCardBuilderTest methodsFor: 'tests' stamp: 'MA 7/13/2020 15:03:08'!
test05CardNumberMustBe16CharactersLong

	| cardBuilder |
	cardBuilder _ CreditCard builder.
	
	self
		should: [ cardBuilder setNumber: '1234' ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cardBuilder invalidCardNumberLengthErrorMessage equals: anError messageText ].! !

!CreditCardBuilderTest methodsFor: 'tests' stamp: 'MA 7/13/2020 17:51:53'!
test06CardCannotBeBuiltUntilAllFieldsHaveBeenAssigned

	| cardBuilder |
	cardBuilder _ CreditCard builder.

	cardBuilder setNumber: '1234567812345678'.
	cardBuilder setOwner: 'nombre apellido'.
	cardBuilder setValidFrom: '07/20'.

	self
		should: [ cardBuilder build ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: cardBuilder missingFieldsErrorMessage equals: anError messageText ].! !

!CreditCardBuilderTest methodsFor: 'tests' stamp: 'MA 7/13/2020 16:13:38'!
test07CardIsOnlyValidWithinValidityPeriod

	| card cardBuilder aDate |
	cardBuilder _ CreditCard builder.

	cardBuilder setNumber: '1234567812345678'.
	cardBuilder setOwner: 'nombre apellido'.
	cardBuilder setValidFrom: '07/20'.
	cardBuilder setValidUntil: '07/24'.
	card _ cardBuilder build.
	
	aDate _ '07/01/20' asDate.	
	self assert: (card isValidOn: aDate).
	
	aDate _ '07/31/24' asDate.	
	self assert: (card isValidOn: aDate).
	
	aDate _ '06/30/20' asDate.	
	self deny: (card isValidOn: aDate).
	
	aDate _ '08/01/24' asDate.	
	self deny: (card isValidOn: aDate).

! !


!classDefinition: #SpyTest category: #TusLibros!
TestCase subclass: #SpyTest
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!SpyTest methodsFor: 'tests' stamp: 'MA 7/16/2020 15:54:45'!
test00SpyForwardsEveryMessageReceivedToItsSpiedObject

	| aCollection aSpiedCollection anElement |
	
	anElement _ 'xxx'.

	aCollection _ OrderedCollection new.

	aSpiedCollection _ Spy on: aCollection.

	self
		should: [ aSpiedCollection burn: anElement ]
		raise: MessageNotUnderstood.
		
	self
		shouldnt: [ aSpiedCollection add: anElement ]
		raise: MessageNotUnderstood.
		
	
	self assert: aCollection includes: anElement. ! !

!SpyTest methodsFor: 'tests' stamp: 'MA 7/16/2020 15:58:41'!
test01SpyKnowsIfItHasReceivedNoMessages

	| aCollection aSpiedCollection |
	
	aCollection _ OrderedCollection new.

	aSpiedCollection _ Spy on: aCollection.
	
	self assert: aSpiedCollection receivedNoMessages.
	
	aSpiedCollection add: '1'.
	
	self deny: aSpiedCollection receivedNoMessages.
! !

!SpyTest methodsFor: 'tests' stamp: 'MA 7/16/2020 16:08:39'!
test02SpyRemembersHowManyTotalMessagesItReceived

	| aCollection aSpiedCollection |
	
	aCollection _ OrderedCollection new.

	aSpiedCollection _ Spy on: aCollection.
	
	aSpiedCollection add: '1'.
	aSpiedCollection add: '2'.
	aSpiedCollection add: '3'.
	aSpiedCollection first.
	aSpiedCollection last.
	
	self assert: 5 equals: (aSpiedCollection messagesReceivedCount).! !

!SpyTest methodsFor: 'tests' stamp: 'MA 7/16/2020 16:11:56'!
test03SpyRemembersHowManyTimesItReceivedASpecificMessage

	| aCollection aSpiedCollection |
	
	aCollection _ OrderedCollection new.

	aSpiedCollection _ Spy on: aCollection.
	
	self assert: 0 equals: (aSpiedCollection timesReceivedSelector: #add:).
		
	aSpiedCollection add: '1'.
	aSpiedCollection add: '2'.
	aSpiedCollection add: '3'.
	aSpiedCollection first.
	aSpiedCollection last.
	
	self assert: 3 equals: (aSpiedCollection timesReceivedSelector: #add:).! !

!SpyTest methodsFor: 'tests' stamp: 'MA 7/16/2020 16:26:13'!
test04SpyRemembersForEachMessageWhatArgumentsItReceived

	| aCollection aSpiedCollection elemX elemY elemZ |
	
	aCollection _ OrderedCollection new.
	
	elemX _ 'x'.
	elemY _ 'y'.
	elemZ _ 'z'.

	aSpiedCollection _ Spy on: aCollection.
		
	aSpiedCollection add: '1'.
	aSpiedCollection add: '2'.
	aSpiedCollection add: '3'.
	aSpiedCollection at: 1 put: elemX.
	aSpiedCollection at: 2 put: elemY.
	aSpiedCollection at: 3 put: elemZ.
	
	self assert: 3 equals: (aSpiedCollection timesReceivedSelector: #at:put:).
	
	self assert: 1 equals: (aSpiedCollection timesReceivedSelector: #at:put: withArgs: { 1. elemX. } ).! !


!classDefinition: #TestDoubleTest category: #TusLibros!
TestCase subclass: #TestDoubleTest
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!TestDoubleTest methodsFor: 'tests' stamp: 'MA 7/16/2020 15:17:03'!
test01TestDoubleCannotHandleMessagesThatHaveNotBeenDefined

	| aCreditCard |
	aCreditCard _ TestDouble new.

	self
		should: [ aCreditCard isValidOn: 'xxx' ]
		raise: Error - MessageNotUnderstood
		withExceptionDo: [ :anError |
			self assert: TestDouble behaviourNotDefinedErrorDescription equals: anError messageText ]! !

!TestDoubleTest methodsFor: 'tests' stamp: 'MA 7/16/2020 15:37:11'!
test02TestDoubleCanHandleMessagesOnceTheyHaveBeenDefined

	| aCreditCard theArg result |
	
	aCreditCard _ TestDouble new.
	
	theArg _ 'xxxxx'.

	aCreditCard when: #isValidOn: do: [ :anArg | anArg ].
	
	result _ aCreditCard isValidOn: theArg.
	
	self assert: theArg equals: result.! !


!classDefinition: #Cart category: #TusLibros!
Object subclass: #Cart
	instanceVariableNames: 'catalog items'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!Cart methodsFor: 'error messages' stamp: 'HernanWilkinson 6/17/2013 17:45'!
invalidItemErrorMessage
	
	^'Item is not in catalog'! !

!Cart methodsFor: 'error messages' stamp: 'HernanWilkinson 6/17/2013 17:45'!
invalidQuantityErrorMessage
	
	^'Invalid number of items'! !


!Cart methodsFor: 'assertions' stamp: 'MA 7/12/2020 21:12:28'!
assertIsValidItem: anItem

	(catalog includesKey: anItem) ifFalse: [ self error: self invalidItemErrorMessage ]! !

!Cart methodsFor: 'assertions' stamp: 'HernanWilkinson 6/17/2013 17:51'!
assertIsValidQuantity: aQuantity

	aQuantity strictlyPositive ifFalse: [ self error: self invalidQuantityErrorMessage ]! !


!Cart methodsFor: 'initialization' stamp: 'HernanWilkinson 6/17/2013 17:48'!
initializeAcceptingItemsOf: aCatalog

	catalog := aCatalog.
	items := OrderedCollection new.! !


!Cart methodsFor: 'queries' stamp: 'HernanWilkinson 6/17/2013 17:45'!
occurrencesOf: anItem

	^items occurrencesOf: anItem  ! !


!Cart methodsFor: 'testing' stamp: 'HernanWilkinson 6/17/2013 17:44'!
includes: anItem

	^items includes: anItem ! !

!Cart methodsFor: 'testing' stamp: 'HernanWilkinson 6/17/2013 17:44'!
isEmpty
	
	^items isEmpty ! !


!Cart methodsFor: 'operations' stamp: 'HernanWilkinson 6/17/2013 17:44'!
add: anItem

	^ self add: 1 of: anItem ! !

!Cart methodsFor: 'operations' stamp: 'HernanWilkinson 6/17/2013 17:51'!
add: aQuantity of: anItem

	self assertIsValidQuantity: aQuantity.
	self assertIsValidItem: anItem.

	1 to: aQuantity do: [ :aNumber | items add: anItem ]! !

!Cart methodsFor: 'operations' stamp: 'MA 7/12/2020 23:36:41'!
clear
	[ items isEmpty ] whileFalse: [ items removeFirst ]! !


!Cart methodsFor: 'accessing' stamp: 'MA 7/12/2020 21:24:32'!
totalValue
	^ items inject: 0 into: [ :sum :each | sum + (catalog at: each) ]! !

"-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- "!

!classDefinition: 'Cart class' category: #TusLibros!
Cart class
	instanceVariableNames: ''!

!Cart class methodsFor: 'instance creation' stamp: 'HernanWilkinson 6/17/2013 17:48'!
acceptingItemsOf: aCatalog

	^self new initializeAcceptingItemsOf: aCatalog ! !


!classDefinition: #CashierPerSale category: #TusLibros!
Object subclass: #CashierPerSale
	instanceVariableNames: 'catalog salesCount earnings salesBook merchantProcessor'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!CashierPerSale methodsFor: 'initialization' stamp: 'MA 7/13/2020 21:55:44'!
initializeUsingSalesBook: aSalesBook merchantProcessor: aMerchantProcessor  
	salesBook _ aSalesBook.
	merchantProcessor _ aMerchantProcessor.! !


!CashierPerSale methodsFor: 'accessing' stamp: 'MA 7/13/2020 20:55:35'!
earnings
	^ earnings.! !

!CashierPerSale methodsFor: 'accessing' stamp: 'MA 7/13/2020 20:55:35'!
salesCount
	^ salesCount.! !


!CashierPerSale methodsFor: 'operations' stamp: 'MA 7/13/2020 22:24:43'!
checkout: aCart payingWith: aCreditCard onDate: aDate

	| amountToDebit |
	
	self assertValidCart: aCart.
	self assertValidCard: aCreditCard onDate: aDate.
	
	amountToDebit  _ aCart totalValue.
	
	merchantProcessor debit: amountToDebit from: aCreditCard. 
	
	salesBook add: amountToDebit.
	
	aCart clear.! !


!CashierPerSale methodsFor: 'error messages' stamp: 'MA 7/13/2020 20:55:35'!
emptyCartErrorMessage
	^ 'cannot checkout on an empty cart'! !

!CashierPerSale methodsFor: 'error messages' stamp: 'MA 7/13/2020 20:55:35'!
invalidCreditCardErrorMessage
	^ 'cannot checkout using an invalid credit card'.! !


!CashierPerSale methodsFor: 'assertions' stamp: 'MA 7/14/2020 18:42:49'!
assertValidCard: aCreditCard onDate: aDate

	(aCreditCard isValidOn: aDate) ifFalse: [ self error: self invalidCreditCardErrorMessage ]! !

!CashierPerSale methodsFor: 'assertions' stamp: 'MA 7/14/2020 20:28:57'!
assertValidCart: aCart
	(aCart isEmpty) ifTrue: [ self error: self emptyCartErrorMessage ]! !

"-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- "!

!classDefinition: 'CashierPerSale class' category: #TusLibros!
CashierPerSale class
	instanceVariableNames: 'catalog'!

!CashierPerSale class methodsFor: 'instance creation' stamp: 'MA 7/13/2020 21:55:06'!
usingSalesBook: aSalesBook usingMerchantProcessor: aMerchantProcessor  
	^self new initializeUsingSalesBook: aSalesBook merchantProcessor: aMerchantProcessor ! !


!classDefinition: #CreditCard category: #TusLibros!
Object subclass: #CreditCard
	instanceVariableNames: 'number owner validFrom validUntil'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!CreditCard methodsFor: 'validation' stamp: 'MA 7/13/2020 16:16:08'!
isValidOn: aDate
	| start end |
	
	start _ Date newDay: 1 month: (validFrom monthName) year: (validFrom yearNumber).
	end _ Date newDay: 1 month: (validUntil next monthName) year: (validUntil next yearNumber).
	
	^ aDate next > start and: aDate < end.
	! !


!CreditCard methodsFor: 'initialization' stamp: 'MA 7/13/2020 15:41:14'!
initializeWithNumber: aNumberAsString withOwner: aName withDateFrom: aMonthYearFromAsString withDateUntil: aMonthYearUntilAsString 
	number := aNumberAsString.
	owner := aName.
	validFrom := aMonthYearFromAsString.
	validUntil := aMonthYearUntilAsString.! !

"-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- "!

!classDefinition: 'CreditCard class' category: #TusLibros!
CreditCard class
	instanceVariableNames: ''!

!CreditCard class methodsFor: 'builder' stamp: 'MA 7/12/2020 22:49:49'!
builder
	^ CreditCardBuilder new.! !


!CreditCard class methodsFor: 'instance creation' stamp: 'MA 7/13/2020 15:40:05'!
withNumber: aNumberAsString withOwner: aName withDateFrom: aMonthYearFromAsString withDateUntil: aMonthYearUntilAsString 
	^self new initializeWithNumber: aNumberAsString withOwner: aName withDateFrom: aMonthYearFromAsString withDateUntil: aMonthYearUntilAsString. ! !


!classDefinition: #CreditCardBuilder category: #TusLibros!
Object subclass: #CreditCardBuilder
	instanceVariableNames: 'number owner dateFrom dateUntil'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!CreditCardBuilder methodsFor: 'setters' stamp: 'MA 7/13/2020 15:41:39'!
setNumber: aNumberAsString

	self assertValidCardNumberLength: aNumberAsString.
	
	self assertValidCardNumberFormat: aNumberAsString .
	
	number _ aNumberAsString! !

!CreditCardBuilder methodsFor: 'setters' stamp: 'MA 7/13/2020 15:42:33'!
setOwner: aName
	self assertValidOwner: aName.
	
	owner _ aName.! !

!CreditCardBuilder methodsFor: 'setters' stamp: 'MA 7/13/2020 15:58:02'!
setValidFrom: aDateAsString
	self assertValidDateFormat: aDateAsString.
	
	dateFrom _ aDateAsString asMonth.! !

!CreditCardBuilder methodsFor: 'setters' stamp: 'MA 7/13/2020 15:58:12'!
setValidUntil: aDateAsString 
	self assertValidDateFormat: aDateAsString.
	
	dateUntil _ aDateAsString asMonth.! !


!CreditCardBuilder methodsFor: 'error messages' stamp: 'MA 7/13/2020 14:32:54'!
invalidCardNumberFormatErrorMessage
	^ 'card number must only contain numeric characters'! !

!CreditCardBuilder methodsFor: 'error messages' stamp: 'MA 7/13/2020 14:36:18'!
invalidCardNumberLengthErrorMessage
	^ 'card number must be 16 digits long'. ! !

!CreditCardBuilder methodsFor: 'error messages' stamp: 'MA 7/13/2020 13:31:48'!
invalidDateFormatErrorMessage
	^ 'string provided cannot be parsed into a valid date'! !

!CreditCardBuilder methodsFor: 'error messages' stamp: 'MA 7/13/2020 14:46:02'!
invalidOwnerErrorMessage
	^ 'owner name cannot be empty'! !

!CreditCardBuilder methodsFor: 'error messages' stamp: 'MA 7/13/2020 15:36:42'!
missingFieldsErrorMessage
	^ 'cannot create card with missing fields'.! !


!CreditCardBuilder methodsFor: 'assertions' stamp: 'MA 7/13/2020 20:29:15'!
assertNothingIsMissing
	(owner isNil
		or: dateFrom isNil
		or: dateUntil isNil
		or: number isNil)
			ifTrue: [ Error signal: self missingFieldsErrorMessage ]! !

!CreditCardBuilder methodsFor: 'assertions' stamp: 'MA 7/13/2020 15:25:42'!
assertValidCardNumberFormat: aNumberAsString

	aNumberAsString do: [ :char | char isDigit ifFalse: [ Error signal: self invalidCardNumberFormatErrorMessage ] ].! !

!CreditCardBuilder methodsFor: 'assertions' stamp: 'MA 7/13/2020 14:43:03'!
assertValidCardNumberLength: aNumberAsString

	^ aNumberAsString size = 16 ifFalse: [ Error signal: self invalidCardNumberLengthErrorMessage ]! !

!CreditCardBuilder methodsFor: 'assertions' stamp: 'MA 7/13/2020 14:44:41'!
assertValidDateFormat: aString

	^ [ aString asMonth ]
	on: Error
	do: [ Error signal: self invalidDateFormatErrorMessage. ]! !

!CreditCardBuilder methodsFor: 'assertions' stamp: 'MA 7/13/2020 15:31:18'!
assertValidOwner: aString 
	(aString size between: 1 and: 30) ifFalse: [ Error signal: self invalidOwnerErrorMessage ].! !


!CreditCardBuilder methodsFor: 'building' stamp: 'MA 7/13/2020 17:45:32'!
build
	self assertNothingIsMissing.
	
	^ CreditCard
		withNumber: number
		withOwner: owner
		withDateFrom: dateFrom
		withDateUntil: dateUntil.! !


!classDefinition: #MerchantProcessor category: #TusLibros!
Object subclass: #MerchantProcessor
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!MerchantProcessor methodsFor: 'operations' stamp: 'MA 7/13/2020 21:28:42'!
debit: anAmount from: aCreditCard
	self subclassResponsibility .! !


!classDefinition: #TestDouble category: #TusLibros!
Object subclass: #TestDouble
	instanceVariableNames: 'customMethodDictionary methodCalls'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!TestDouble methodsFor: 'initialization' stamp: 'MA 7/16/2020 17:00:07'!
initialize
	customMethodDictionary  _ Dictionary new.
! !


!TestDouble methodsFor: 'operations' stamp: 'MA 7/14/2020 20:25:55'!
actUpon: aMessage
	| block result |
	block _ customMethodDictionary at: aMessage selector.
	result _ block valueWithArguments: aMessage arguments.
	^ result.! !

!TestDouble methodsFor: 'operations' stamp: 'MA 7/16/2020 16:59:53'!
doesNotUnderstand: aMessage
	self assertBehaviourHasBeenSetFor: aMessage.
	^ self actUpon: aMessage.
! !

!TestDouble methodsFor: 'operations' stamp: 'MA 7/14/2020 17:17:14'!
when: aSelector do: aBlock
	customMethodDictionary at: aSelector put: aBlock.! !


!TestDouble methodsFor: 'assertions' stamp: 'MA 7/14/2020 17:14:36'!
assertBehaviourHasBeenSetFor: aMessage
	(customMethodDictionary includesKey: aMessage selector) ifFalse: [
		self error: self class behaviourNotDefinedErrorDescription.
	].! !

"-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- "!

!classDefinition: 'TestDouble class' category: #TusLibros!
TestDouble class
	instanceVariableNames: ''!

!TestDouble class methodsFor: 'error handling' stamp: 'MA 7/14/2020 16:55:13'!
behaviourNotDefinedErrorDescription

	^ 'selector has no associated behaviour in mock object'! !


!classDefinition: #Spy category: #TusLibros!
ProtoObject subclass: #Spy
	instanceVariableNames: 'methodCalls spiedObject'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'TusLibros'!

!Spy methodsFor: 'initialization' stamp: 'MA 7/16/2020 15:43:33'!
initialize
	methodCalls _ Dictionary new.! !

!Spy methodsFor: 'initialization' stamp: 'MA 7/16/2020 15:46:19'!
initializeOn: anObject
	spiedObject _ anObject.! !


!Spy methodsFor: 'operations' stamp: 'MA 7/16/2020 16:53:37'!
doesNotUnderstand: aMessage
	self countMessage: aMessage.
	^ aMessage sendTo: spiedObject.! !


!Spy methodsFor: 'accessing' stamp: 'MA 7/16/2020 15:35:52'!
messagesReceivedCount
	^ methodCalls keys inject: 0 into: [ :accum :key | accum + (methodCalls at: key) size ].! !

!Spy methodsFor: 'accessing' stamp: 'MA 7/16/2020 15:35:52'!
receivedNoMessages
	^ self messagesReceivedCount = 0.! !

!Spy methodsFor: 'accessing' stamp: 'MA 7/16/2020 15:35:52'!
timesReceivedSelector: aSelector
	^ (methodCalls at: aSelector ifAbsent: [ #() ]) size.! !

!Spy methodsFor: 'accessing' stamp: 'MA 7/16/2020 16:36:21'!
timesReceivedSelector: aSelector withArgs: anArrayOfArgs
	| argsReceived |
	argsReceived _ methodCalls at: aSelector ifAbsent: [ OrderedCollection new ].
	^ (argsReceived select: [ :arrOfArgs | self elemsIn: arrOfArgs matchElemsIn: anArrayOfArgs ]) size.
! !


!Spy methodsFor: 'private' stamp: 'MA 7/16/2020 16:52:32'!
countMessage: aMessage
	(methodCalls includesKey: aMessage selector) ifFalse: [ methodCalls at: aMessage selector put: OrderedCollection new ].
	
	(methodCalls at: aMessage selector) add: aMessage arguments.! !

!Spy methodsFor: 'private' stamp: 'MA 7/16/2020 15:35:52'!
elemsIn: collection1 matchElemsIn: collection2

	(collection1 size = collection2 size) ifFalse: [ ^ false ].
	
	(1 to: collection1 size) do: [ :index | ((collection1 at: index) = (collection2 at: index)) ifFalse: [^ false ] ].
	
	^ true.
	
	! !

"-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- "!

!classDefinition: 'Spy class' category: #TusLibros!
Spy class
	instanceVariableNames: ''!

!Spy class methodsFor: 'instance creation' stamp: 'MA 7/16/2020 15:45:45'!
on: anObject
	^ self new initializeOn: anObject.
! !